Customizing the Calendar and Diary
**********************************

There are many customizations that you can use to make the calendar and diary suit your personal tastes.

Customizing the Calendar
========================

If you set the variable view-diary-entries-initially to t, calling up the calendar automatically displays the diary entries for the current date as well.  The diary dates appear only if the current date is visible.  If you add both of the following lines to your .emacs file:

     (setq view-diary-entries-initially t)
     (calendar)

they display both the calendar and diary windows whenever you start Emacs.

Similarly, if you set the variable view-calendar-holidays-initially to t, entering the calendar automatically displays a list of holidays for the current three month period.  The holiday list appears in a separate window.

You can set the variable mark-diary-entries-in-calendar to t in order to place a plus sign (+) beside any dates with diary entries. Whenever the calendar window is displayed or redisplayed, the diary entries are automatically marked for holidays.

Similarly, setting the variable mark-holidays-in-calendar to t places an asterisk (*) after all holiday dates visible in the calendar window.

There are many customizations that you can make with the hooks provided.  For example, the variable calendar-load-hook, whose default value is nil, is a normal hook run when the calendar package is first loaded (before actually starting to display the calendar).

The variable initial-calendar-window-hook, whose default value is nil, is a normal hook run the first time the calendar window is displayed.  The function is invoked only when you first enter Calendar mode, not when you redisplay an existing Calendar window.  But if you leave the calendar with the q command and reenter it, the hook runs again.

The variable today-visible-calendar-hook, whose default value is nil, is a normal hook run after the calendar buffer has been prepared with the calendar when the current date is visible in the window.  One use of this hook is to replace today's date with asterisks; a function calendar-star-date is included for this purpose.  In your .emacs file, put:

     (setq today-visible-calendar-hook 'calendar-star-date)

Another standard hook function adds asterisks around the current date. Here's how to use it:

     (setq today-visible-calendar-hook 'calendar-mark-today)

A corresponding variable, today-invisible-calendar-hook, whose default value is nil, is a normal hook run after the calendar buffer text has been prepared, if the current date is not visible in the window.

Customizing the Holidays
========================

Emacs knows about holidays defined by entries on one of several lists. You can customize theses lists of holidays to your own needs, adding holidays or deleting lists of holidays.  The lists of holidays that Emacs uses are for general holidays (general-holidays), local holidays (local-holidays), Christian holidays (christian-holidays), Hebrew (Jewish) holidays (hebrew-holidays), Islamic (Moslem) holidays (islamic-holidays), and other holidays (other-holidays).

The general holidays are, by default, holidays common throughout the United States.  To eliminate these holidays, set general-holidays to nil.

There are no default local holidays (but sites may supply some).  You can set the variable local-holidays to any list of holidays, as described below.

By default, Emacs does not consider all the holidays of these religions, only those commonly found in secular calendars.  For a more extensive collection of religious holidays, you can set any (or all) of the variables all-christian-calendar-holidays, all-hebrew-calendar-holidays, or all-islamic-calendar-holidays to t.  If you want to eliminate the religious holidays, set any or all of the corresponding variables christian-holidays, hebrew-holidays, and islamic-holidays to nil.

You can set the variable other-holidays to any list of holidays.  This list, normally empty, is intended for your use.

Each of the lists (general-holidays), (local-holidays), (christian-holidays), (hebrew-holidays), (islamic-holidays),and (other-holidays) is a list of holiday forms, each holiday form describing a holiday (or sometimes a list of holidays).  Holiday forms may have the following formats:

(fixed MONTH DAY STRING)
     A fixed date on the Gregorian calendar.  MONTH and DAY are numbers, STRING is the name of the holiday.

(float MONTH DAYNAME K STRING)
     The Kth DAYNAME in MONTH on the Gregorian calendar (DAYNAME=0 for Sunday, and so on); negative K means count back from the end of the month.  STRING is the name of the holiday.

(hebrew MONTH DAY STRING)
     A fixed date on the Hebrew calendar.  MONTH and DAY are numbers, STRING is the name of the holiday.

(islamic MONTH DAY STRING)
     A fixed date on the Islamic calendar.  MONTH and DAY are numbers, STRING is the name of the holiday.

(julian MONTH DAY STRING)
     A fixed date on the Julian calendar.  MONTH and DAY are numbers, STRING is the name of the holiday.

(sexp SEXP STRING)
     SEXP is a Lisp expression that should use the variable year to compute the date of a holiday, or nil if the holiday doesn't happen this year.  The value represents the date as a list of the form (MONTH DAY YEAR).  STRING is the name of the holiday.

(if BOOLEAN HOLIDAY-FORM &optional HOLIDAY-FORM)
     A choice between two holidays based on the value of BOOLEAN.

(FUNCTION &optional ARGS)
     Dates requiring special computation; ARGS, if any, are passed in a list to the function calendar-holiday-function-FUNCTION.

For example, suppose you want to add Bastille Day, celebrated in France on July 14.  You can do this by adding the following line to your .emacs file:

     (setq other-holidays '((fixed 7 14 "Bastille Day")))

The holiday form (fixed 7 14 "Bastille Day") specifies the fourteenth day of the seventh month (July).

Many holidays occur on a specific day of the week, at a specific time of month.  Here is a holiday form describing Hurricane Supplication Day, celebrated in the Virgin Islands on the fourth Monday in August:

     (float 8 1 4 "Hurricane Supplication Day")

Here the 8 specifies August, the 1 specifies Monday (Sunday is 0, Tuesday is 2, and so on), and the 4 specifies the fourth occurrence in the month (1 specifies the first occurrence, 2 the second occurrence, -1 the last occurrence, -2 the second-to-last occurrence, and so on).

You can specify holidays that occur on fixed days of the Hebrew, Islamic, and Julian calendars too.  For example,

     (setq other-holidays
           '((hebrew 10 2 "Last day of Hanukkah")
             (islamic 3 12 "Mohammed's Birthday")
             (julian 4 2 "Jefferson's Birthday")))

adds the last day of Hanukkah (since the Hebrew months are numbered with 1 starting from Nisan), the Islamic feast celebrating Mohammed's birthday (since the Islamic months are numbered from 1 starting with Muharram), and Thomas Jefferson's birthday, which is 2 April 1743 on the Julian calendar.

To include a holiday conditionally, use either the if or the sexp form.  For example, American presidential elections occur on the first Tuesday after the first Monday in November of years divisible by 4:

     (sexp (if (= 0 (% year 4))
               (calendar-gregorian-from-absolute
                 (1+ (calendar-dayname-on-or-before
                        1 (+ 6 (calendar-absolute-from-gregorian
                                 (list 11 1 year))))))
           "US Presidential Election"))

or

     (if (= 0 (% displayed-year 4))
         (fixed 11
                (extract-calendar-day
                  (calendar-gregorian-from-absolute
                    (1+ (calendar-dayname-on-or-before
                          1 (+ 6 (calendar-absolute-from-gregorian
                                   (list 11 1 displayed-year)))))))
                "US Presidential Election"))

Some holidays just don't fit into any of these forms because special calculations are involved in their determination.  In such cases you must write a Lisp function to do the calculation.  The function should return a (possibly empty) list of the relevant Gregorian dates among the range visible in the calendar window, with descriptive strings, like this:

     (((6 27 1991) "Lunar Eclipse") ((7 11 1991) "Solar Eclipse") ... )

Date Display Format
===================

You can customize the manner of displaying dates in the diary, in mode lines, and in messages by setting calendar-date-display-form.  This variable is a list of expressions that can involve the variables month, day, and year, all numbers in string form, and monthname and dayname, both alphabetic strings.  In the American style, the default value of this list is as follows:

     ((if dayname (concat dayname ", ")) monthname " " day ", " year)

while in the European style this value is the default:

     ((if dayname (concat dayname ", ")) day " " monthname " " year)

The ISO standard date representation is this:

     (year "-" month "-" day)

This specifies a typical American format:

     (month "/" day "/" (substring year -2))

Time Display Format
===================

In the calendar, diary, and related buffers, Emacs displays times of day in the conventional American style with the hours from 1 through 12, minutes, and either am or pm.  If you prefer the ``military'' (European) style of writing times---in which the hours go from 00 to 23---you can alter the variable calendar-time-display-form.  This variable is a list of expressions that can involve the variables 12-hours, 24-hours, and minutes, all numbers in string form, and am-pm and time-zone, both alphabetic strings.  The default definition of calendar-time-display-form is as follows:

     (12-hours ":" minutes am-pm (if time-zone " (") time-zone (if time-zone ")"))

Setting calendar-time-display-form to

     (24-hours ":" minutes (if time-zone " (") time-zone (if time-zone ")"))

gives military-style times like 21:07 (UT) if time zone names are defined, and times like 21:07 if they are not.

Daylight Savings Time
=====================

Emacs understands the difference between standard time and daylight savings time---the times given for sunrise, sunset, solstices, equinoxes, and the phases of the moon take that into account.  The default starting and stopping dates for daylight savings time are the present-day American rules of the first Sunday in April until the last Sunday in October, but you can specify whatever rules you want by setting calendar-daylight-savings-starts and calendar-daylight-savings-ends.  Their values should be Lisp expressions that refer to the variable year, and evaluate to the Gregorian date on which daylight savings time starts or (respectively) ends, in the form of a list (MONTH DAY YEAR).

Emacs uses these expressions to determine the starting date of daylight savings time for the holiday list and for correcting times of day in the solar and lunar calculations.

The default value of calendar-daylight-savings-starts is this,

     (calendar-nth-named-day 1 0 4 year)

which computes the first 0th day (Sunday) of the fourth month (April) in the year specified by year.  If daylight savings time were changed to start on October 1, you would set calendar-daylight-savings-starts to

     (list 10 1 year)

For a more complex example, suppose daylight savings time begins on the first of Nisan on the Hebrew calendar.  You would set calendar-daylight-savings-starts to

     (calendar-gregorian-from-absolute
       (calendar-absolute-from-hebrew
         (list 1 1 (+ year 3760))))

because Nisan is the first month in the Hebrew calendar and the Hebrew year differs from the Gregorian year by 3760 at Nisan.

If there is no daylight savings time at your location, or if you want all times in standard time, set calendar-daylight-savings-starts and calendar-daylight-savings-ends to nil.

Customizing the Diary
=====================

Ordinarily, the mode line of the diary buffer window indicates any holidays that fall on the date of the diary entries.  The process of checking for holidays can take several seconds, so including holiday information delays the display of the diary buffer noticeably.  If you'd prefer to have a faster display of the diary buffer but without the holiday information, set the variable holidays-in-diary-buffer to nil.

The variable number-of-diary-entries controls the number of days of diary entries to be displayed at one time.  It affects the initial display when view-diary-entries-initially is t, as well as the command M-x diary.  For example, the default value is 1, which says to display only the current day's diary entries.  If the value is 2, both the current day's and the next day's entries are displayed.  The value can also be a vector of seven elements: if the value is [0 2 2 2 2 4 1] then no diary entries appear on Sunday, the current date's and the next day's diary entries appear Monday through Thursday, Friday through Monday's entries appear on Friday, while on Saturday only that day's entries appear.

The variable print-diary-entries-hook is a normal hook run after preparation of a temporary buffer containing just the diary entries currently visible in the diary buffer.  (The other, irrelevant diary entries are really absent from the temporary buffer; in the diary buffer, they are merely hidden.)  The default value of this hook does the printing with the command lpr-buffer.  If you want to use a different command to do the printing, just change the value of this hook.  Other uses might include, for example, rearranging the lines into order by day and time.

You can customize the form of dates in your diary file, if neither the standard American nor European styles suits your needs, by setting the variable diary-date-forms.  This variable is a list of forms of dates recognized in the diary file.  Each form is a list of regular expressions (see Regular Expressions) and the variables month, day, year, monthname, and dayname.  The variable monthname matches the name of the month, capitalized or not, or its three-letter abbreviation, followed by a period or not; it matches *.  Similarly, dayname matches the name of the day, capitalized or not, or its three-letter abbreviation, followed by a period or not.  The variables month, day, and year match those numerical values, preceded by arbitrarily many zeros; they also match *.  The default value of diary-date-forms in the American style is

     ((month "/" day "[^/0-9]")
      (month "/" day "/" year "[^0-9]")
      (monthname " *" day "[^,0-9]")
      (monthname " *" day ", *" year "[^0-9]")
      (dayname "\\W"))

Emacs matches of the diary entries with the date forms is done with the standard syntax table from Fundamental mode (see Syntax Tables), but with the * changed so that it is a word constituent.

The forms on the list must be mutually exclusive and must not match any portion of the diary entry itself, just the date.  If, to be mutually exclusive, the pattern must match a portion of the diary entry itself, the first element of the form must be backup. This causes the date recognizer to back up to the beginning of the current word of the diary entry.  Even if you use backup, the form must absolutely not match more than a portion of the first word of the diary entry.  The default value of diary-date-forms in the European style is this list:

     ((day "/" month "[^/0-9]")
      (day "/" month "/" year "[^0-9]")
      (backup day " *" monthname "\\W+\\<[^*0-9]")
      (day " *" monthname " *" year "[^0-9]")
      (dayname "\\W"))

Notice the use of backup in the middle form because part of the diary entry must be matched to distinguish this form from the following one.

Hebrew- and Islamic-Date Diary Entries
======================================

Your diary file can have entries based on Hebrew or Islamic dates, as well as entries based on our usual Gregorian calendar.  However, because the processing of such entries is time-consuming and most people don't need them, you must customize the processing of your diary file to specify that you want such entries recognized.  If you want Hebrew-date diary entries, for example, you must include these lines in your .emacs file:

     (setq nongregorian-diary-listing-hook 'list-hebrew-diary-entries)
     (setq nongregorian-diary-marking-hook 'mark-hebrew-diary-entries)

If you want Islamic-date entries, include these lines in your .emacs file:

     (setq nongregorian-diary-listing-hook 'list-islamic-diary-entries)
     (setq nongregorian-diary-marking-hook 'mark-islamic-diary-entries)

If you want both Hebrew- and Islamic-date entries, include these lines:

     (setq nongregorian-diary-listing-hook
           '(list-hebrew-diary-entries list-islamic-diary-entries))
     (setq nongregorian-diary-marking-hook
           '(mark-hebrew-diary-entries mark-islamic-diary-entries))

Hebrew- and Islamic-date diary entries have the same formats as Gregorian-date diary entries, except that the date must be preceded with an H for Hebrew dates and an I for Islamic dates. Moreover, because the Hebrew and Islamic month names are not uniquely specified by the first three letters, you may not abbreviate them.  For example, a diary entry for the Hebrew date Heshvan 25 could look like

     HHeshvan 25 Happy Hebrew birthday!

and would appear in the diary for any date that corresponds to Heshvan 25 on the Hebrew calendar.  Similarly, an Islamic-date diary entry might be

     IDhu al-Qada 25 Happy Islamic birthday!

and would appear in the diary for any date that corresponds to Dhu al-Qada 25 on the Islamic calendar.

As with Gregorian-date diary entries, Hebrew- and Islamic-date entries are nonmarking if they are preceded with an ampersand (&).

There are commands to help you in making Hebrew- and Islamic-date entries to your diary:

i h d
     Add a diary entry for the Hebrew date corresponding to the selected date (insert-hebrew-diary-entry).

i h m
     Add a diary entry for the day of the Hebrew month corresponding to the selected date (insert-monthly-hebrew-diary-entry).

i h y
     Add a diary entry for the day of the Hebrew year corresponding to the selected date (insert-yearly-hebrew-diary-entry).

i i d
     Add a diary entry for the Islamic date corresponding to the selected date (insert-islamic-diary-entry).

i i m
     Add a diary entry for the day of the Islamic month corresponding to the selected date (insert-monthly-islamic-diary-entry).

i i y
     Add a diary entry for the day of the Islamic year corresponding to the selected date (insert-yearly-islamic-diary-entry).

These commands work exactly like the corresponding commands for ordinary diary entries: Move point to a date in the calendar window and the above commands insert the Hebrew or Islamic date (corresponding to the date indicated by point) at the end of your diary file and you can then type the diary entry.  If you want the diary entry to be nonmarking, give a numeric argument to the command.

Fancy Diary Display
===================

Diary display works by preparing the diary buffer and then running the hook diary-display-hook.  The default value of this hook hides the irrelevant diary entries and then displays the buffer (simple-diary-display).  However, if you specify the hook as follows,

     (add-hook 'diary-display-hook 'fancy-diary-display)

then fancy mode displays diary entries and holidays by copying them into a special buffer that exists only for display.  Copying provides an opportunity to change the displayed text to make it prettier---for example, to sort the entries by the dates they apply to.

As with simple diary display, you can print a hard copy of the buffer with print-diary-entries.  To print a hard copy of a day-by-day diary for a week by positioning point on Sunday of that week, type 7 d and then do M-x print-diary-entries.  As usual, the inclusion of the holidays slows down the display slightly; you can speed things up by setting the variable holidays-in-diary-buffer to nil.

Ordinarily, the fancy diary buffer does not show days for which there are no diary entries, even if that day is a holiday.  If you want such days to be shown in the fancy diary buffer, set the variable diary-list-include-blanks to t.

If you use the fancy diary display, you can use the normal hook list-diary-entries-hook to sort each day's diary entries by their time of day.  Add this line to your .emacs file:

     (add-hook 'list-diary-entries-hook 'sort-diary-entries)

For each day, this sorts diary entries that begin with a recognizable time of day according to their times.  Diary entries without times come first within each day.

Included Diary Files
====================

If you use the fancy diary display, you can have diary entries from other files included with your own by an ``include'' mechanism.  This facility makes possible the sharing of common diary files among groups of users.  Lines in the diary file of this form:

     #include "FILENAME"

includes the diary entries from the file FILENAME in the fancy diary buffer (because the ordinary diary buffer is just the buffer associated with your diary file, you cannot use the include mechanism unless you use the fancy diary buffer).  The include mechanism is recursive, by the way, so that included files can include other files, and so on; you must be careful not to have a cycle of inclusions, of course.  To enable the include facility, add lines as follows to your .emacs file:

     (add-hook 'list-diary-entries-hook 'include-other-diary-files)
     (add-hook 'mark-diary-entries-hook 'mark-included-diary-files)

Sexp Entries and the Fancy Diary Display
========================================

Sexp diary entries allow you to do more than just have complicated conditions under which a diary entry applies.  If you use the fancy diary display, sexp entries can generate the text of the entry depending on the date itself.  For example, an anniversary diary entry can insert the number of years since the anniversary date into the text of the diary entry.  Thus the %d in this dairy entry:

     %%(diary-anniversary 10 31 1948) Arthur's birthday (%d years old)

gets replaced by the age, so on October 31, 1990 the entry appears in the fancy diary buffer like this:

     Arthur's birthday (42 years old)

If the diary file instead contains this entry:

     %%(diary-anniversary 10 31 1948) Arthur's %d%s birthday

the entry in the fancy diary buffer for October 31, 1990 appears like this:

     Arthur's 42nd birthday

Similarly, cyclic diary entries can interpolate the number of repetitions that have occurred:

     %%(diary-cyclic 50 1 1 1990) Renew medication (%d%s time)

looks like this:

     Renew medication (5th time)

in the fancy diary display on September 8, 1990.

The generality of sexp diary entries lets you specify any diary entry that you can describe algorithmically.  Suppose you get paid on the 21st of the month if it is a weekday, and to the Friday before if the 21st is on a weekend.  The diary entry

     &%%(let ((dayname (calendar-day-of-week date))
              (day (car (cdr date))))
           (or (and (= day 21) (memq dayname '(1 2 3 4 5)))
               (and (memq day '(19 20)) (= dayname 5)))
              ) Pay check deposited

applies to just those dates.  This example illustrates how the sexp can depend on the variable date; this variable is a list (MONTH DAY YEAR) that gives the Gregorian date for which the diary entries are being found.  If the value of the expression is t, the entry applies to that date.  If the expression evaluates to nil, the entry does not apply to that date.

The following sexp diary entries take advantage of the ability (in the fancy diary display) to concoct diary entries based on the date:

%%(diary-sunrise-sunset)
     Make a diary entry for the local times of today's sunrise and sunset.

%%(diary-phases-of-moon)
     Make a diary entry for the phases (quarters) of the moon.

%%(diary-day-of-year)
     Make a diary entry with today's day number in the current year and the number of days remaining in the current year.

%%(diary-iso-date)
     Make a diary entry with today's equivalent ISO commercial date.

%%(diary-julian-date)
     Make a diary entry with today's equivalent date on the Julian calendar.

%%(diary-astro-day-number)
     Make a diary entry with today's equivalent astronomical (Julian) day number.

%%(diary-hebrew-date)
     Make a diary entry with today's equivalent date on the Hebrew calendar.

%%(diary-islamic-date)
     Make a diary entry with today's equivalent date on the Islamic calendar.

%%(diary-french-date)
     Make a diary entry with today's equivalent date on the French Revolutionary calendar.

%%(diary-mayan-date)
     Make a diary entry with today's equivalent date on the Mayan calendar.

Thus including the diary entry

     &%%(diary-hebrew-date)

causes every day's diary display to contain the equivalent date on the Hebrew calendar, if you are using the fancy diary display.  (With simple diary display, the line &%%(diary-hebrew-date) appears in the diary for any date, but does nothing particularly useful.)

There are a number of other available sexp diary entries that are important to those who follow the Hebrew calendar:

%%(diary-rosh-hodesh)
     Make a diary entry that tells the occurrence and ritual announcement of each new Hebrew month.

%%(diary-parasha)
     Make a Saturday diary entry that tells the weekly synagogue scripture reading.

%%(diary-sabbath-candles)
     Make a Friday diary entry that tells the local time of Sabbath candle lighting.

%%(diary-omer)
     Make a diary entry that gives the omer count, when appropriate.

%%(diary-yahrzeit MONTH DAY YEAR) NAME
     Make a diary entry marking the anniversary of a date of death.  The date is the Gregorian (civil) date of death.  The diary entry appears on the proper Hebrew calendar anniversary and on the day before.  (In the European style, the order of the parameters is changed to DAY, MONTH, YEAR.)

Customizing Appointment Reminders
=================================

You can specify exactly how Emacs reminds you of an appointment and how far in advance it begins doing so.  Here are the variables that you can set:

appt-message-warning-time
     The time in minutes before an appointment that the reminder begins.  The default is 10 minutes.

appt-audible
     If this is t (the default), Emacs rings the terminal bell for appointment reminders.

appt-visible
     If this is t (the default), Emacs displays the appointment message in echo area.

appt-display-mode-line
     If this is t (the default), Emacs displays the number of minutes to the appointment on the mode line.

appt-msg-window
     If this is t (the default), Emacs displays the appointment message in another window.

appt-display-duration
     The number of seconds an appointment message is displayed.  The default is 5 seconds.